home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1995 #5 & #6 / Amiga Plus CD - 1995 - No. 5 and 6.iso / tex / mf / inputs / dc / dxrlig.mf < prev    next >
Text File  |  1994-04-12  |  10KB  |  216 lines
  1. % This is DXRLIG.MF in text format, as of March 24, 1992
  2. %
  3. % DC fonts Version 1.1 (prerelease of EC fonts)
  4. %
  5. %          [ heavily borrowed from the Computer Modern Roman family of
  6. %            fonts by D. E. Knuth ]
  7. %
  8. % Content:
  9. %
  10. %  roman style ligature characters
  11. %
  12. %  dotless i,j; ligatures  fi, ff, fl, ffi, ffl
  13. %
  14.  
  15.  
  16. dcchar "Dotless letter i";
  17. beginchar(oct"031",5u#,x_height#,0);
  18. italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
  19. adjust_fit(serif_fit#+stem_shift# if monospace:+.25u#fi,serif_fit#-stem_shift#);
  20. pickup tiny.nib; pos1(stem',0); pos2(stem',0);
  21. if odd(w-stem'): change_width; fi
  22. lft x1l=hround(.5w-.5stem'); x1=x2;
  23. top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=0;
  24. filldraw stroke z1e--z2e;  % stem
  25. if serifs: sloped_serif.l(1,2,a,1/3,.95jut,serif_drop);  % upper serif
  26.  dish_serif(2,1,b,1/3,jut,c,1/3,.9jut); fi  % lower serif
  27. penlabels(1,2); endchar;
  28.  
  29. dcchar "Dotless letter j";
  30. beginchar(oct"032",5.5u#,x_height#,desc_depth#);
  31. italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
  32. adjust_fit(serif_fit#+2stem_shift# if monospace:+.5u# fi,
  33.  serif_fit#-2stem_shift# if monospace:-.5u# fi);
  34. pickup tiny.nib; pos1(stem',0); pos2(stem',0);
  35. rt x1r=hround(.5w+.25u+.5stem'); x1=x2;
  36. top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=-1/3d;
  37. filldraw stroke z1e--z2e;  % stem
  38. if serifs: sloped_serif.l(1,2,a,1/3,1.1jut,serif_drop);  % upper serif
  39.  pickup tiny.nib; pos5(vair,-90); pos6(hair,-180); pos7(flare,-180);
  40.  x5=.5[x2,x6r]; bot y5r=-d-oo; y6-.5flare=-.88d;
  41.  if monospace: lft x6r=0 else: z6r=z7r; rt x7l=floor .75u fi;
  42.  (x,y5r)=whatever[z5l,z2l]; x5r:=max(x,.5[x6r,x5]);
  43.  filldraw stroke z2e{down}...z5e{left};  bulb(5,6,7); % arc and bulb
  44. else: pickup fine.nib; pos2'(stem',0); z2'=z2;
  45.  pos6(.2[vair,stem'],-90); pos7(vair,-90);
  46.  lft x7r=hround -.75u; bot y7r=vround 5/6(-d-oo);
  47.  x3r=x1r; top y4r=min(2x_height,h+1);
  48.  (x,y7l)=whatever[z7r,(x1,min(h,asc_height))]; x7l:=x;
  49.  z5r=z2'r; (x2'l,y5l)=whatever[z7l,z5r]; x5l=x2'l; y5=y5r;
  50.  x6r=.5[x7r,x5r]; x6l:=.5[x7l,x5l]; bot y6r=-d-oo;
  51.  filldraw stroke z2'e..{down}z5e & super_arc.e(5,6)
  52.   & term.e(6,7,left,1,4); fi  % arc and terminal
  53. penlabels(1,2,5,6,7); endchar;
  54.  
  55.  
  56. numeric itc#; % modified italic correction on `f' and `ff'
  57. itc#=if serifs: max(0,flare#-.25u#) else: 1.25u# fi;
  58.  
  59.  
  60. dcchar "The ligature fi";
  61. beginchar(oct"034",10u#+2letter_fit#,asc_height#,0);
  62. italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
  63. normal_adjust_fit(0,serif_fit#);
  64. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  65. pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
  66. pos12(stem',0); x11=x12; bot y12=0;
  67. pickup fine.nib; numeric bulb_diam, inner_jut;
  68. if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
  69.  pos2(bulb_diam,0); x2r=x12r;
  70.  y2+.5bulb_diam=.8[x_height,h+oo]; top y11=x_height+min(oo,serif_drop);
  71.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  72.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  73. else: bulb_diam=max(stem,dot_size);
  74.  pos2(6/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u;
  75.  pickup tiny.nib; pos13(bulb_diam,0); pos14(bulb_diam,90);
  76.  x13=x11-.5; top y14r=min(2x_height,h+1); top y11=x_height;
  77.  if bot y14l-x_height<tiny: y14l:=min(y14r-eps,y11+2tiny); fi
  78.  x13=x14; y13=.5[y14l,y14r]; dot(13,14);  % dot
  79. fi;  % this is the ligature we're drawing
  80. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  81. pickup tiny.nib; filldraw stroke z11e--z12e;  % right stem
  82. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  83. pos3(bar,90); pos4(bar,90);
  84. if serifs: x4=x11;  % bar will overlap upper right serif
  85.  sloped_serif.l(11,12,d,1/3,jut,min(oo,serif_drop));  % upper right serif
  86.  dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut);  % lower right serif
  87. else: rt x4= hround 5.3u; fi
  88. pickup crisp.nib; filldraw stroke z3e--z4e;  % bar
  89. penlabels(1,2,3,4,11,12,13,14); endchar;
  90.  
  91.  
  92. dcchar "The ligature ff";
  93. beginchar(oct"033",10.5u#+2letter_fit#,asc_height#,0);
  94. italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
  95. normal_adjust_fit(0,0);
  96. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  97. pos11(stem',0); rt x11r=hround(w-3u+.5stem');
  98. pickup fine.nib; numeric bulb_diam, inner_jut;
  99. if serifs: bulb_diam=hround .8[stem,flare];
  100.  pos2(bulb_diam,0); pos12(bulb_diam,0);
  101.  rt x2r=hround(rt x11r-stem_corr); lft x12l=hround(w-.75u+.5);
  102.  y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
  103.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  104.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  105. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 6.25u;
  106.  pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(w+.75u); fi
  107. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  108. f_stroke(11,12,d,e,f,inner_jut,1.25jut); % right stem, arc, terminal, serif
  109. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  110. pos3(bar,90); pos4(bar,90);
  111. rt x4=hround(w-1/3u);
  112. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  113.  pos4'(bar,90); x4'=x11; y4'=y4;
  114.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  115. else: filldraw stroke z3e--z4e; fi  % bar
  116. penlabels(1,2,3,4,11,12); endchar;
  117.  
  118.  
  119. dcchar "The ligature fl";
  120. beginchar(oct"035",10u#+2letter_fit#,asc_height#,0);
  121. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  122. normal_adjust_fit(0,serif_fit#);
  123. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  124. pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
  125. pos12(stem',0); x11=x12; bot y12=0; top y11=h;
  126. filldraw stroke z11e--z12e;  % right stem
  127. pickup fine.nib; numeric bulb_diam, inner_jut;
  128. if serifs: bulb_diam=hround .8[stem,flare];
  129.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  130.  y2+.5bulb_diam=.9[x_height,h+oo];
  131.  sloped_serif.l(11,12,d,1/3,eps,max(serif_drop,oo)); % erase excess at top
  132.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  133.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  134. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u; fi
  135. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  136. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  137. pos3(bar,90); pos4(bar,90);
  138. if serifs: x4=x11;
  139.  dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut);  % lower right serif
  140. else: rt x4= hround 5.3u; fi
  141. pickup crisp.nib; filldraw stroke z3e--z4e;  % bar
  142. penlabels(1,2,3,4,11,12); endchar;
  143.  
  144. dcchar "The ligature ffi";
  145. beginchar(oct"036",15u#+4letter_fit#,asc_height#,0);
  146. italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
  147. normal_adjust_fit(0,serif_fit#);
  148. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  149. pos11(stem',0); lft x11l=hround(.5w-.5stem');
  150. pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
  151. pos22(stem',0); x21=x22; bot y22=0;
  152. pickup fine.nib; numeric bulb_diam, inner_jut;
  153. if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
  154.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  155.  pos12(bulb_diam,0); x12r=x21r;
  156.  top y21=x_height+min(oo,serif_drop);
  157.  y2+.5bulb_diam=.8[x_height,h+oo]; y12=y2;
  158.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  159.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  160. else: bulb_diam=max(stem,dot_size);
  161.  pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
  162.  pos12(6/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u);
  163.  pickup tiny.nib; pos23(bulb_diam,0); pos24(bulb_diam,90);
  164.  x23=x21-.5; top y24r=min(2x_height,h+1); top y21=x_height;
  165.  if bot y24l-x_height<tiny: y24l:=min(y24r-eps,y21+2tiny); fi
  166.  x23=x24; y23=.5[y24l,y24r]; dot(23,24); fi  % dot
  167. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  168. f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
  169. pickup tiny.nib; filldraw stroke z21e--z22e;  % right stem
  170. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
  171. pos3(bar,90); pos4(bar,90);
  172. if serifs: x4=x21;  % bar will overlap upper right serif
  173.  sloped_serif.l(21,22,g,1/3,jut,min(oo,serif_drop));  % upper right serif
  174.  dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut);  % lower right serif
  175. else: rt x4=hround(.5w+2.8u); fi
  176. pickup crisp.nib;
  177. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  178.  pos4'(bar,90); x4'=x11; y4'=y4;
  179.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  180. else: filldraw stroke z3e--z4e; fi  % bar
  181. penlabels(1,2,3,4,11,12,21,22,23,24); endchar;
  182.  
  183. dcchar "The ligature ffl";
  184. beginchar(oct"037",15u#+4letter_fit#,asc_height#,0);
  185. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  186. normal_adjust_fit(0,serif_fit#);
  187. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  188. pos11(stem',0); lft x11l=hround(.5w-.5stem');
  189. pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
  190. pos22(stem',0); x21=x22; bot y22=0; top y21=h;
  191. filldraw stroke z21e--z22e;  % right stem
  192. pickup fine.nib; numeric bulb_diam, inner_jut;
  193. if serifs: bulb_diam=hround .8[stem,flare];
  194.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  195.  pos12(bulb_diam,0); x12r=x21r-stem_corr;
  196.  y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
  197.  sloped_serif.l(21,22,g,1/3,eps,max(serif_drop,oo)); % erase excess at top
  198.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  199.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  200. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
  201.  pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u); fi
  202. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  203. f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
  204. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
  205. pos3(bar,90); pos4(bar,90);
  206. if serifs: dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut);  % lower right serif
  207.  pickup crisp.nib; x4=x21;
  208. else: rt x4=hround(.5w+2.8u); fi
  209. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  210.  pos4'(bar,90); x4'=x11; y4'=y4;
  211.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  212. else: filldraw stroke z3e--z4e; fi  % bar
  213. penlabels(1,2,3,4,11,12,21,22); endchar;
  214.  
  215. endinput;
  216.